// Функция РазобратьШК(ШК) Экспорт - Возвращает тип отсканированного ШтрихКода
// 1 	- EAN(13 или 8)	обычный ШК товара
// 2 	- DataMatrix 		пачки сигарет
// 3 	- DataMatrix 		блока сигарет
// 4 	- PDF-417 			алкоголь, старая марка
// 5 	- DataMatrix 		алкоголь,новая марка
// 6 	- DataMatrix		алкоголь, старая марка, "маленький квадратик"
// 7    - DataMatrix 		прочей упаковки сигарет 
// 8	- Сокращенный код маркировки прочих товаров, в том числе молока
// МРЦ	- максимальная розничная цена сигарет
// Тип  - тип старой марки
// Сер	- серия старой марки
// Ном	- номер старой марки  
Функция РазобратьШК(Знач ШК) Экспорт
	СЗ			= СоздатьОбъект("СписокЗначений");
	СтрШК		= СокрЛП(ШК);
	Если СтрДлина(СтрШК) <= 13 Тогда
		СЗ.ДобавитьЗначение(1, 		"ТипЕд");
		СЗ.ДобавитьЗначение(СтрШК, 	"ЕАН");
		СЗ.ДобавитьЗначение(0);
	ИначеЕсли (СтрДлина(СтрШК) <= 29) И (СтрДлина(СтрШК) >= 21) Тогда
		СЗ.ДобавитьЗначение(2, 		"ТипЕд");
		ВыдЕАН	= СокрЛП(Число(Лев(ШК, 14)));
		СЗ.ДобавитьЗначение(ВыдЕАН, "ЕАН");
		Если СтрДлина(СтрШК) >= 25 Тогда
			МРЦ	= ВернутьМРЦ(Сред(СокрЛП(СтрШК), 22, 4));    
		Иначе	
			МРЦ	= 0;	
		КонецЕсли;
		СЗ.ДобавитьЗначение(МРЦ, "МРЦ");
	ИначеЕсли СтрДлина(СтрШК) = 68 Тогда
		СЗ.ДобавитьЗначение(4, 		"ТипЕд");
		СЗ.ДобавитьЗначение(СтрШК, 	"ЕАН");
		СЗ.ДобавитьЗначение(0);
	ИначеЕсли СтрДлина(СтрШК) = 150 Тогда	
		СЗ.ДобавитьЗначение(5, 		"ТипЕд");
		СЗ.ДобавитьЗначение(СтрШК, 	"ЕАН");
		СЗ.ДобавитьЗначение(0);
	ИначеЕсли (СтрДлина(СтрШК) >= 30) И (СтрДлина(СтрШК) < 68) Тогда	
		Если Сред(СтрШК,4,1) 	= "-" Тогда
			Тип	= Лев(СтрШК,3);
			СтрТипа = "";
			СзТиповМарок	= ЗаполнитьСписокТиповМарок();
			Поз	= СзТиповМарок.НайтиЗначение(Число(Тип));			
			Если Поз 	= 0 Тогда
				Предупреждение("Тип марки не найден!");
			Иначе
				СзТиповМарок.ПолучитьЗначение(Поз,СтрТипа);
			КонецЕсли;			
			Если Найти(СтрТипа,"ФСМ. ") > 0 Тогда
				ДлинаНомераМарки=9; 
			Иначе
				ДлинаНомераМарки=8 
			КонецЕсли;
		 	СЗ.ДобавитьЗначение(6, "ТипЕд");
			СЗ.ДобавитьЗначение(СтрШК);
			СЗ.ДобавитьЗначение(0);
			СЗ.ДобавитьЗначение(Лев(ШК,3), СокрЛП(СтрТипа));
			СЗ.ДобавитьЗначение(Сред(ШК,Найти(ШК,"-") + 1,3));
			СЗ.ДобавитьЗначение(Сред(ШК,Найти(ШК,"-") + 4,ДлинаНомераМарки));
		Иначе
			СтрШК				= СтрЗаменить(СтрШК, "(", "");
			СтрШК				= СтрЗаменить(СтрШК, ")", "");
			Если Лев(СтрШК, 2) 	= "01"  Тогда
				Если Найти(СтрШК, Симв(29)) > 0 Тогда               // Марка полная, со сканера
					СЗ.ДобавитьЗначение(7, 		"ТипЕд");
					GTIN		= Сред(СтрШК, 3, 14);	
					ШК			= СокрЛП(Число(Сред(СтрШК, 3, 14)));
					СЗ.ДобавитьЗначение(ШК, 	"ЕАН");
					СЗ.ДобавитьЗначение(GTIN, 	"GTIN");
					СЗ.ДобавитьЗначение(0, 		"МРЦ");
				Иначе	
					Если  Найти(СтрШК, "8005") = 0 Тогда
						// Упаковка, отличная от блока
						GTIN	= СокрЛП(Число(Сред(СтрШК, 3, 14)));
						МРЦ 	= 0;
						Если Лев(GTIN, 1) = "0" Тогда
						    ЕАН	= Сред(GTIN, 2, 13);
						Иначе
							ЕАН	= Лев(GTIN, 13);
						КонецЕсли;
						СЗ.ДобавитьЗначение(7, 		"ТипЕд");
						СЗ.ДобавитьЗначение(ЕАН, 	"ЕАН");
						СЗ.ДобавитьЗначение(МРЦ, 	"МРЦ");
						СЗ.ДобавитьЗначение(GTIN, 	"GTIN");
						СЗ.ДобавитьЗначение(ПривестиШкБлокаКВидуУПД(СтрШК), "ШКУПД");
					ИначеЕсли Найти(СтрШК, "8005") >= 25 Тогда
				    	ШК	= СокрЛП(Число(Сред(СтрШК, 3, 14)));
						МРЦ = ВычислитьМРЦ_Блока(СтрШК);
						СЗ.ДобавитьЗначение(3, 		"ТипЕд");
						СЗ.ДобавитьЗначение(ШК, 	"ЕАН");
						СЗ.ДобавитьЗначение(МРЦ, 	"МРЦ");
						СЗ.ДобавитьЗначение(ПривестиШкБлокаКВидуУПД(СтрШК), "ШКУПД");	
					КонецЕсли;
				КонецЕсли;	
			КонецЕсли;  
		КонецЕсли;
	ИначеЕсли (СтрДлина(СтрШК) >= 19) И (СтрДлина(СтрШК) < 21) Тогда // Молочка и другой товар сокращенные
		ШК	= СокрЛП(Число(Сред(СтрШК, 3, 14)));
		СЗ.ДобавитьЗначение(8, 								"ТипЕд");
		СЗ.ДобавитьЗначение(ШК, 							"ЕАН");
		СЗ.ДобавитьЗначение(0, 								"МРЦ");
		СЗ.ДобавитьЗначение(ПривестиШкБлокаКВидуУПД(СтрШК), "ШКУПД");		
	КонецЕсли;	
	Возврат СЗ;
КонецФункции
// КонецФункци РазобратьШК(ШК)