Подскажите плиз...
Задача такая, необходимо ЗАПРОСОМ получить последние 2 записи по регистру сведений с одним измерений.
Должно получиться что-то вроде этого:

Товар | Класс предпоследний | Класс последний

(0) А  класс предпоследний и последний могут совпадать?

(1) Да

(2) Хотя по логике, может и не совпадать. Но кто его знает кто будет "завтра трогать код".

может не оптимально, но работает

ВЫБРАТЬ
    СрезПоследних.ФизЛицо,
    СрезПоследних.Фамилия,
    СрезПредПоследних.Фамилия КАК ФамилияПред
ИЗ
    РегистрСведений.ФИОФизЛиц.СрезПоследних КАК СрезПоследних
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ФИОФизЛиц.СрезПоследних(
                ,
                НЕ (ФизЛицо, Период) В
                        (ВЫБРАТЬ
                            СрезПоследних.ФизЛицо,
                            СрезПоследних.Период
                        ИЗ
                            РегистрСведений.ФИОФизЛиц.СрезПоследних КАК СрезПоследних)) КАК СрезПредПоследних
        ПО СрезПоследних.ФизЛицо = СрезПредПоследних.ФизЛицо

(4) Вариант интересный, но каково будет если имеется более 10 000 товаров...

(5) попробуй. Не факт, что коррелированный запрос или двойное соединение с живой таблицей по максимум(период) будет оптимальнее

(6) Попробовал, но выдаёт одинаковую информацию( т.е. выдаёт в двух случаях последние данные)

(4) Выполнил запрос, но не сработало...

Есть варианты?

Вот тут написано как модифицировать регистр чтобы легко получать любые срезы
https://naf2000.blogspot.com/2013/09/1-8_11.html?m=1

На партнерке давно было года три назад. Использую.

// срез последних двух
ВЫБРАТЬ *
ИЗ РегистрСведений.КурсыВалют Курсы
ГДЕ Курсы.Период < &Дата
и Курсы.Период в (
  ВЫБРАТЬ ПЕРВЫЕ 2 К.Период
  ИЗ РегистрСведений.КурсыВалют К
  ГДЕ К.Период < &Дата и К.Валюта = Курсы.Валюта
  УПОРЯДОЧИТЬ ПО К.Период УБЫВ

  )

(7) Значит последнее значение совпадает с предпоследним

+(12) или запрос адаптировал неправильно. "НЕ" не потерял?

(11) Вот он - коррелированный запрос

(12) Значения разные...
(13) "НЕ" не потерял...

(15) запрос покажи и результат желательно

(16)
ВЫБРАТЬ
    ПоследниеПоказатели.Товар КАК Товар,
    ПоследниеПоказатели.Период КАК ПоследнийПериод,
    ПоследниеПоказатели.КлассТовара КАК ПоследнийКлассТовара,
    ПредПоследниеПоказатели.Период КАК ПредПоследнийПериод,
    ПредПоследниеПоказатели.КлассТовара КАК ПредПоследнийКлассТовара
ИЗ
    РегистрСведений.ПериодическиеПараметрыТовара.СрезПоследних КАК ПоследниеПоказатели
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ПериодическиеПараметрыТовара.СрезПоследних(
                ,
                НЕ (Период, Товар) В
                        (ВЫБРАТЬ
                            ПериодическиеПараметрыТовара.Товар,
                            ПериодическиеПараметрыТовара.Период
                        ИЗ
                            РегистрСведений.ПериодическиеПараметрыТовара.СрезПоследних КАК ПериодическиеПараметрыТовара)) КАК ПредПоследниеПоказатели
        ПО ПоследниеПоказатели.Товар = ПредПоследниеПоказатели.Товар

(16)
Результат https://priscree.ru/img/92cf20f4d925e6.jpg

(17) (Период, Товар) идут в другом порядке в условии

(19) ааааа....жесть)))

Спасибо большое! (19)

(21) по скорости то норм?

(22) 16 000 строк за 0,8 секунд.

(23) норм, а (11) не пробовал?

(19) С чем связанно этот порядок? Раз е тут не соблюдается условие "И" ?

(25) Проверяется совпадение пары (набора). Порядок конечно важен

(26) Буду иметь ввиду.

(24) Попробовал отбирает действительно 2 последних от даты запроса.

но скажем так мне желательно получить это одной строкой а двум записям. Дабы исключить дальнейшую дообработку.

(28) это понятно:) Вопрос про время выполнения, интересно насколько коррелированные запросы могут применяться на реальных задачах

(30) Разница тем и этим в 1,6 секунд. Первый вариант быстрее.

(31) Спасибо. Медленнее заметно. Но если нужно будет, например 5 последних, то вариант уже будет вероятно оптимальным.

(32) Согласен.
и ещё если. Если в первый запрос, добавить дата запроса, то всё, не работает корректно.

(33) >> Если в первый запрос, добавить дата запроса
Должно работать, параметр нужно в 3х местах прописать

(34) Соррян, указал в двух местах(
"Засыпал")

Огромное спасибо!